[Setting] - QueryDSL 설정하기

 

 

 

 

 

 

 

자바 

buildscript {
    ext {
        queryDslVersion = "5.0.0"
    }
}

plugins {
   id 'org.springframework.boot' version '3.0.2'
   id 'io.spring.dependency-management' version '1.1.0'
   id 'java'

}

group = 'com.example'
version = '0.0.1-SNAPSHOT'
sourceCompatibility = '17'

configurations {
   compileOnly {
      extendsFrom annotationProcessor
   }
}

repositories {
   mavenCentral()
}

dependencies {
   implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
   implementation 'org.springframework.boot:spring-boot-starter-web'
   compileOnly 'org.projectlombok:lombok'
   runtimeOnly 'com.h2database:h2'
   annotationProcessor 'org.projectlombok:lombok'
   testImplementation 'org.springframework.boot:spring-boot-starter-test'


	// QueryDSL 설정
    implementation "com.querydsl:querydsl-jpa:${queryDslVersion}:jakarta"
    implementation "com.querydsl:querydsl-core"
    implementation "com.querydsl:querydsl-collections"
	
    // 스프링부트 3.0 이전 annotationProcessor "com.querydsl:querydsl-apt:${queryDslVersion}:jpa"
    annotationProcessor "com.querydsl:querydsl-apt:${queryDslVersion}:jakarta"
    
	annotationProcessor "jakarta.persistence:jakarta.persistence-api" // java.lang.NoClassDefFoundError (javax.annotation.Entity) 대응 코드
	annotationProcessor "jakarta.annotation:jakarta.annotation-api" // java.lang.NoClassDefFoundError (javax.annotation.Generated) 대응 코드
   
   
}

tasks.named('test') {
   useJUnitPlatform()
}


// == QueryDSL 추가 설정 == //
// QueryDSL 생성 파일 위치 -> 이를 설정해주지 않으면 build 디렉토리에 생성되는데, 인텔리제이에서 문제가 될수도 있음
// IntelliJ 빌드 시 스캔하는 영역과 Gradle 빌드 시 스캔하는 영역이 달라서 발생하는 오류 해결
def generated = 'src/main/generated'

tasks.withType(JavaCompile) {
	options.getGeneratedSourceOutputDirectory().set(file(generated))
}

// java source set 에 QueryDSL Q class 위치 추가
sourceSets {
	main.java.srcDirs += [ generated ]
}


// gradle clean 시에 QClass 디렉토리 삭제
clean {
	delete file(generated)
}

 

 

 

 

스프링부트 3 이후

   annotationProcessor "com.querydsl:querydsl-apt:${queryDslVersion}:jpa"

해당 부분이 아래와 같이 바뀝니다.

annotationProcessor "com.querydsl:querydsl-apt:${queryDslVersion}:jakarta"

 

 

 

 

 

 

 

 

 

 

 

 

 

 

Reference 

https://www.inflearn.com/questions/583088

Querydsl 설정 과 빌드 질문 입니다. - 인프런 | 질문 & 답변

https://dev-gorany.tistory.com/362

[Spring Boot] Kotlin Querydsl 적용 (with. Mono repo, Multi module)

http://honeymon.io/tech/2020/07/09/gradle-annotation-processor-with-querydsl.html

[gradle] 그레이들 Annotation processor 와 Querydsl - I'm honeymon(JiHeon Kim).